Sharp PC-E500/E500S Technikersoftware

ME-FRM.321

Mechanische Formeln

ME-FRM.321 (3.993 Bytes)

10 ' MECHANIC.321 (Mechanical formula)
15 CLEAR
20 MERGE "G:COMN.00$"
30 ON ERROR GOTO *ERR
40 GOSUB *CG
50 QB0$=CHR$ &B0:QC3$=CHR$ &C3:QB1$=CHR$ &B1:QA5$=CHR$ &A5:QAD$=CHR$ &AD:QA7$=CHR$ &A7
60 QD2$=CHR$ &D2:QD3$=CHR$ &D3:QB3$=CHR$ &B3:QA3$=CHR$ &A3:QEA$=CHR$ &EA:QAC$=CHR$ &AC
70 DIM QX$(12,2),Q8$(7),Q8(7)
80 QX$(1,1)="Module (M=D"+QD2$+"/Z"+QD2$+"=D"+QD3$+"/Z"+QD3$+"=P/"+QB0$+")"
90 QX$(1,2)="      M=D"+QD2$+"/Z"+QD2$
100 QX$(2,1)=QX$(1,1)
110 QX$(2,2)="      D"+QD3$+"=D"+QD2$+"Z"+QD3$+"/Z"+QD2$
120 QX$(3,1)=QX$(1,1)
130 QX$(3,2)="      M=P/"+QB0$
140 QX$(4,1)="Bernoulli's theorem"
150 QX$(4,2)="      v"+QC3$+"/2+P/"+QB1$+"+gz=Constant"
160 QX$(5,1)="Equation of continuity"
170 QX$(5,2)="      Av"+QB1$+"=Constant"
180 QX$(6,1)="Reynolds number"
190 QX$(6,2)="      R=LU/"+QAD$
200 QX$(7,1)="Enthalpy"
210 QX$(7,2)="      H=U+pV"
220 QX$(8,1)="Carnot's cycle"
230 QX$(8,2)="      "+QA7$+"=(Q"+QD2$+"-Q"+QD3$+")/Q"+QD2$
240 QX$(9,1)="Carnot's cycle"
250 QX$(9,2)="      "+QA7$+"=(T"+QD2$+"-T"+QD3$+")/T"+QD2$
260 QX$(10,1)="Young's modulus"
270 QX$(10,2)="      E=T/"+QA5$
280 QX$(11,1)="Stress"
290 QX$(11,2)="      "+QB3$+"=P/A"
300 QX$(12,1)="Stress"
310 QX$(12,2)="      "+QB3$+"=G"+QA3$
330 ' menu display
340 QI=1
350 GOSUB 920:GOSUB 930
360 QWW$=RIGHT$ (QCL$,38-LEN QX$(QI,1)):LOCATE 2,1:PRINT QX$(QI,1);QWW$
370 QWW$=RIGHT$ (QCL$,38-LEN QX$(QI,2)):LOCATE 2,2:PRINT QX$(QI,2);QWW$
380 ' key wait
390 Q9$=INKEY$ &1:Q9=ASC Q9$
400 WAIT 10:PRINT "";:WAIT 0
410 IF Q9=&4 THEN 450 ELSE IF Q9=&5 THEN 460
420 IF Q9=&D THEN 520
430 IF Q9<&F1 AND Q9>&F5 THEN 390
440 ON Q9-&F0 GOTO 480,470,490,500,510
450 IF QI=1 THEN 380 ELSE QI=QI-1:GOTO 360
460 IF QI=12 THEN 380 ELSE QI=QI+1:GOTO 360
470 QI=QI-3:IF QI>=1 THEN 360
480 QI=1:GOTO 360
490 QI=6:GOTO 360
500 QI=QI+3:IF QI<=12 THEN 360
510 QI=12:GOTO 360
520 ON QI GOTO 540,550,560,580,610,640,670,700,720,740,770,780
530 ' Module
540 R2$="Q8(1)/Q8(2)":Q8$(0)="M":Q8$(1)="D"+QD2$:Q8$(2)="Z"+QD2$:Q5=2:GOTO 800
550 R2$="Q8(1)*Q8(2)/Q8(3)":Q8$(0)="D"+QD3$:Q8$(1)="D"+QD2$:Q8$(2)="Z"+QD3$:Q8$(3)="Z"+QD2$:Q5=3:GOTO 800
560 R2$="Q8(1)/PI":Q8$(0)="M":Q8$(1)="P":Q5=1:GOTO 800
570 ' Bernoulli's theorem
580 R2$="sqr(2*(Q8(1)-Q8(2))/Q8(3)+Q8(4)^2+2*Q8(5)*(Q8(6)-Q8(7)))"
590 Q8$(0)="v"+QD3$:Q8$(1)="P"+QD2$:Q8$(2)="P"+QD3$::Q8$(3)=QB1$
600 Q8$(4)="v"+QD2$:Q8$(5)="g":Q8$(6)="z"+QD2$:Q8$(7)="z"+QD3$:Q5=7:GOTO 800
610 ' Equation of continuity
620 R2$="Q8(1)*Q8(2)*Q8(3)/Q8(4)/Q8(5)
630 Q8$(0)="v"+QD3$:Q8$(1)="A"+QD2$:Q8$(2)="v"+QD2$:Q8$(3)=QB1$+QD2$:Q8$(4)="A"+QD3$:Q8$(5)=QB1$+QD3$:Q5=5:GOTO 800
640 ' Reynolds number
650 R2$="(Q8(1)*Q8(2))/Q8(3)"
660 Q8$(0)="R":Q8$(1)="L":Q8$(2)="U":Q8$(3)=QAD$:Q5=3:GOTO 800
670 ' Enthatpy
680 R2$="Q8(1)+Q8(2)*Q8(3)"
690 Q8$(0)="H":Q8$(1)="U":Q8$(2)="p":Q8$(3)="V":Q5=3:GOTO 800
700 ' Carnot's cycle
710 Q8$(1)="Q"+QD2$:Q8$(2)="Q"+QD3$:GOTO 730
720 Q8$(1)="T"+QD2$:Q8$(2)="T"+QD3$
730 Q8$(0)=QA7$:R2$="(Q8(1)-Q8(2))/Q8(1)":Q5=2:GOTO 800
740 ' Young's modulus
750 R2$="Q8(1)/Q8(2)":Q8$(0)="E":Q8$(1)="T":Q8$(2)=QA5$:Q5=2:GOTO 800
760 ' Stress
770 R2$="Q8(1)/Q8(2)":Q8$(0)=QB3$:Q8$(1)="P":Q8$(2)="A":Q5=2:GOTO 800
780 R2$="Q8(1)*Q8(2)":Q8$(0)=QB3$:Q8$(1)="G":Q8$(2)=QA3$:Q5=2:GOTO 800
790 ' Calc.
800 FOR QJ=1 TO Q5:Q8(QJ)=0:NEXT
810 '
820 CLS :PRINT QX$(QI,2)
830 FOR QJ=1 TO Q5
840 PRINT "  "+Q8$(QJ)+"= ";:Q9$="":INPUT Q9$
850 IF Q9$="" THEN 350 ELSE Q8(QJ)=EVAL Q9$
860 NEXT
870 Q8(0)=EVAL R2$
880 CLS :PRINT QX$(QI,2)
890 LOCATE 3,3:PRINT Q8$(0)+"=";Q8(0)
900 GOSUB *REK:GOTO 800
910 CLS :PRINT QX$(QI,2):GOSUB *DPA:GOTO 900
920 CLS :LOCATE 9,0:PRINT "*  MECHANICAL FORMULAS  *":RETURN
930 LOCATE 0,3:PRINT "[      ][      ][CENTER][      ][      ]"
940 GCURSOR (22,31):GPRINT "09057F0509"
950 GCURSOR (70,31):GPRINT "4466776644"
960 GCURSOR (166,31):GPRINT "1133773311"
970 GCURSOR (214,31):GPRINT "48507F5048":RETURN
1000 *ERR IF ERL =850 RESUME 840
1010 GOSUB 920:GOSUB *DPA:GOSUB *REK:RESUME 80

Generated by (c) Casio FX-850P/FX-880P Notepad 2.02

(c) by mani.becker@web.de - http://blog.manib.bplaced.net