Sharp PC-E500/E500S Technikersoftware

F.414

F-Verteilung

F.414 (1.227 Bytes)

10 ' DFF.414 (F-distribution)
15 CLEAR
20 MERGE "G:SBDF.42$":MERGE "G:COMN.00$"
30 ON ERROR GOTO *ERR
40 GOSUB *CG
50 ' Display menu
60 CLS :LOCATE 10,0:PRINT "*  F DISTRIBUTION  *"
70 LOCATE 6,2:PRINT "F(p)...1         F(x)...2"
80 ' Select menu number
90 Q9$=INKEY$ &1
100 IF Q9$="1" THEN 120
110 IF Q9$="2" THEN 260 ELSE 90
120 ' Calc F(p)
130 CLS
140 P3$="  n1= ":GOSUB 600
150 IF Q9$="" THEN 50 ELSE Q5=Q9
160 IF Q5-INT Q5<>0 OR Q5<=0 THEN 140
170 P3$="  n2= ":GOSUB 600
180 IF Q9$="" THEN 50 ELSE P5=Q9
190 IF P5-INT P5<>0 OR P5<=0 THEN 170
200 P3$="  p (0<p"+CHR$ &E5+"1)= ":GOSUB 600
210 IF Q9$="" THEN 50 ELSE P6=Q9
220 IF P6<=0 OR P6>1 THEN 200
230 R5=0:GOSUB *FP:IF R5 THEN 140
240 QXQ=QX:QYQ=-5:GOSUB *RNDN:QX=QXQ:PRINT "  x=";QX
250 GOTO 140
260 ' Calc F(x)
270 CLS
280 P3$="  n1= ":GOSUB 600
290 IF Q9$="" THEN 50 ELSE Q5=Q9
300 IF Q5-INT Q5<>0 OR Q5<=0 THEN 280
310 P3$="  n2= ":GOSUB 600
320 IF Q9$="" THEN 50 ELSE P5=Q9
330 IF P5-INT P5<>0 OR P5<=0 THEN 310
340 P3$="  x= ":GOSUB 600
350 IF Q9$="" THEN 50 ELSE QX=Q9:IF QX<0 THEN 385
360 R5=0:GOSUB *FU:IF R5 THEN 280
370 QXQ=P6:QYQ=-5:GOSUB *RNDN:P6=QXQ:PRINT "  p=";P6
380 GOTO 280
385 P6=1:PRINT "  p=";P6:GOTO 280

Generated by (c) Casio FX-850P/FX-880P Notepad 2.02

(c) by mani.becker@web.de - http://blog.manib.bplaced.net