1000 PRINT "Elektronisches Winddreieck      (c) 1999-2011, Ulrich Cordes"
1010 INPUT "Entfernungen:                   1=km  2=knt/Meilen: ",einh
1020 INPUT "Windrichtung [ß]: ",wa
1030 INPUT "Windgeschw. [knt]: ",ws
1040 ANGLE 0
1050 IF einh=1 THEN ws=ws*1.85
1060 IF einh=1 THEN INPUT "Fluggeschw. [km/h]:",tas ELSE INPUT "Fluggeschw. [knt]:",tas
1070 INPUT "Verbrauch [l/h]:", verbh
1080 wa=wa-180
1090 IF wa<0 THEN wa=wa+360
1100 INPUT "Anzahl der Streckenab-          schnitte? ", z
1110 sumzeit=0 : sumverb=0
1120 v=0:dev=0
1130 FOR n=1 TO z
1140 CLS:PRINT "=== Streckenabschnitt ";n;" ==="
1150 INPUT "Kurs [ß]:",tc
1160 IF einh=1 THEN INPUT "Entfernung [km]:",entf ELSE INPUT "Entfernung [NM]:",entf
1170 v=0
1180 INPUT "Variation [ß]:",v
1190 a=tc-wa:wy=ws*SIN(a):wx=ws*COS(a)
1200 wca=0
1210 IF wy<>0 THEN wca=ASN(wy/tas)
1220 tasx=tas*COS(wca)
1230 gs=wx+tasx
1240 ch=INT(tc+wca+v+0.5)
1250 dev=0
1260 PRINT "Deviation fuer ";ch;:INPUT "ß: ",dev
1270 ch=ch-dev
1280 PRINT "Geschw. ueber Grund:";INT(gs+0.5);
1290 IF einh=1 THEN PRINT "km/h" ELSE PRINT "knt"
1300 PRINT "Kompasskurs: ";ch;"ß"
1310 zeit = INT(entf*60/gs*10+0.5)/10
1320 verbs= INT(verbh*zeit/60*10+0.5)/10
1330 PRINT "Zeit:";zeit;"min  Verbr:";verbs;"l"
1340 sumzeit=sumzeit+zeit
1350 sumverb=sumverb+verbs
1360 IF n<z THEN PRINT "kum.Zeit:";sumzeit;"min"
1370 NEXT n
1380 CLS
1390 PRINT "Streckenverbr.:";sumverb;"l"
1400 INPUT "Zeitreserve [min]:",resrv
1410 sumzeit=sumzeit+resrv
1420 PRINT "Gesamtzeit:";sumzeit;"min"
1430 PRINT "Gesamtverbrauch:";INT(verbh*sumzeit/60*10+0.5)/10;"l"
1440 END