Casio FX-850P Horse Race

Horse Race

Ein Pferderennen Spiel von Mario Khni.

Horse Race (2.260 Bytes)

10 REM HORSE RACE
20 CLEAR :DIM A(3,10):SET N
30 R=1:$="ABCDE"
40 PRINT "HORSE RACE           Push [EXE] to start "
50 INPUT "HOW MANY HORSES ";Z : IF Z<2 THEN 50
51 IF Z=9 THEN #1
60 IF Z>5 THEN 50:GOTO 50
70 PRINT "HORSE ";
80 FOR J=1 TO Z: PRINT J; MID$(J,1);:NEXT J
90 GOSUB 1000:GOSUB 1000
100 PRINT
110 INPUT "HOW MANY PLAYERS ";P
120 IF P>10 THEN 110
130 IF P<1 THEN 110
140 PRINT "ALL PLAYERS HAVE $50";
150 GOSUB 1000
160 DIM X(2,P),Y$(P)
170 FOR J=1 TO P:X(2,J)=50:NEXT J
180 REM INITIALZE
190 G=0
200 FOR J=1 TO Z
210 A(1,J)=0:A(2,J)=RAN#:A(3,J)=1+INT(10^(1.2-A(2,J)))
220 NEXT J
230 PRINT :PRINT "RACE";R;:GOSUB 1000
240 REM BET MONEY
250 FOR J=1 TO P
260 PRINT :X(1,J)=0:Y$(J)=" "
270 IF X(2,J)=0 THEN 450
280 PRINT "PLAYER";J;" HAS $";X(2,J);
290 GOSUB 1000
300 PRINT :PRINT "RATE ";
310 FOR K=1 TO Z
320 PRINT CSRK*5; MID$(K,1);A(3,K);
330 NEXT K
340 GOSUB 1000
350 PRINT CSR0;"P";J;"æ";
360 A$= KEY$: IF A$="" THEN 360
370 IF A$<"0" THEN 360
380 IF A$>"5" THEN 360
390 N=VAL(A$): IF N=0 THEN 450
400 A$=MID$(N,1):Y$(J)=A$
410 PRINT :PRINT "PLAYER";J;" HORSE ";A$;
420 INPUT "  MONEY ";X(1,J)
430 IF X(2,J)<X(1,J) THEN 410
440 X(2,J)=X(2,J)-X(1,J)
450 NEXT J
470 CLS:PRINT "START ! -+-+-+-+-+-+-+- FINISHå";
490 PRINT
500 REM MAIN LOOP
510 IF G=2 THEN 600
520 FOR J=1 TO Z
530 IF G>=1 THEN 560
540 PRINT CSRA(1,J);" ";
550 IF RAN#*(0.9+A(2,J)/10)>0.7 THEN A(1,J)=A(1,J)+1
560 IF A(1,J)=30 THEN G=G+1
570 PRINT CSRA(1,J);MID$(J,1);
580 NEXT J
590 GOTO 500
600 REM GOAL
610 PRINT CSR0;"GOAL !";
620 REM  FOR J=1 TO 7:NEXT J
630 GOSUB 1000
640 FOR J=1 TO Z
650 IF A(1,J)=30 THEN H=A(3,J):A$=MID$(J,1)
660 NEXT J
670 F=0
680 FOR J=1 TO P
690 M=0:IF X(1,J)=0 THEN 730
700 IF Y$(J)=A$ THEN M=X(1,J)*H*2
710 PRINT
720 PRINT "PLAYER";J;" æ PRIZE $";M;
730 X(2,J)=X(2,J)+M:GOSUB 1000
740 PRINT :IF X(2,J)=0 THEN F=F+1
750 PRINT "PLAYER";J;" HAS $";X(2,J);:GOSUB 1000
760 NEXT J
770 PRINT :IF F=THEN 830
780 PRINT "REPLAY [Y/N] ?";
790 A$= KEY$: IF A$="" THEN 790
800 IF A$="Y" THEN R=R+1:GOTO 180
810 IF A$="N" THEN 830
820 GOTO 790
830 CLS:PRINT "* * * * *  GAME OVER  * * * * *":GOTO #1
840 END
1000 REM TIMER SUB
1010 FOR K=1 TO 150:NEXT K
1020 RETURN

Generated by (c) Casio FX-850P/FX-880P Notepad 2.03.2

(c) 2015 by Mario Khni - http://blog.manib.bplaced.net